Section courante

A propos

Section administrative du site

Il est très agaçant d'avoir des formules toutes préparés d'avance fonctionnant très bien dans des tableurs et ne pas être capable d'effectuer les mêmes calculs et les mêmes réponses dans une situation anodine de la programmation. Une de ces remarquables fonctions, est celle du Lotus 1-2-3 et de Quattro Pro, elle se nomme la fonction IPaymt en anglais ou Interet en français. A l'aide du code source DarkBASIC suivant, vous trouverez la réponse que vous souhaitez :

PRINT "Prêt hypothécaire de 30 ans à 15% de 200 000$:"
PRINT IPAYMT(0.15/12.0,2.0*12.0,30.0*12.0,200000.0,2.0,0.0)
WAIT KEY

FUNCTION Ln(x#)
    LOCAL negatif,fois#,ajout#,i
    negatif = 0
    fois# = 1
    ajout# = 0
    IF x#<=0.0 THEN ReturnValue#=0:EXITFUNCTION
    IF x#<1.0 THEN negatif = 1:x# = 1.0/x#
    WHILE x# >= 10.0
       x# = x# / 10.0
       ajout# = ajout# + 2.302585092994046
    ENDWHILE
    WHILE x# >= 1.1
       x# = Sqrt(x#)
       fois# = fois# * 2
    ENDWHILE
    DEC x#
    savx# = x#
    i = 2
    xp# = x#*x#
    quotient# = (xp#/i)
    dl# = x#-quotient#
    WHILE 0.000000000000001<quotient#
       INC i
       xp# = xp# * x#
       dl# = dl# + (xp#/i)
       INC i
       xp# = xp# * x#
       quotient# = (xp#/i)
       dl# = dl# - quotient#
    ENDWHILE
    dl# = dl# * fois#
    dl# = dl# + ajout#
    IF negatif=1 THEN dl# = -dl#
    ReturnValue#=dl#
ENDFUNCTION ReturnValue#

FUNCTION FVal(Rate#,NPer#,Pmt#,PV#,PType#)
 F#=Exp(nper#*Ln(1.0+Rate#))
 IF Abs(Rate#)<0.000001
    ReturnValue#=-pmt#*nper#*(1.0+(nper#-1.0)*rate#/2.0)*(1.0+rate#*pType#)-pV#*F#
 ELSE
    ReturnValue#=pmt#*(1-F#)*(1/rate#+pType#)-pV#*F#
 ENDIF
ENDFUNCTION ReturnValue#

FUNCTION Paymt(Rate#, NPer#,PV#,FV#,PType#)
 F#=Exp(NPer#*Ln(1.0+Rate#))
 ReturnValue#=(FV#+PV#*F#)*Rate#/((1+Rate#*PType#)*(1.0-F#))
ENDFUNCTION ReturnValue#

FUNCTION IPAYMT(Rate#,Per#,NPer#,PV#,FV#,PType#)
 ReturnValue#=Rate#*FVal(Rate#,Per#-PType#-1.0,Paymt(Rate#,NPer#,PV#,FV#,PType#),PV#,PType#)
ENDFUNCTION ReturnValue#

on obtiendra le résultat suivant:

Prêt hypothécaire de 30 ans à 15% de 200 000$:
-2490.45$


Dernière mise à jour : Samedi, le 4 octobre 2008