Section courante

A propos

Section administrative du site

Depuis déjà fort longtemps, certaines applications DOS, fournissait la possibilité d'obtenir les phases lunaires lorsqu'on consultait leur calendrier comme en fait fois la capture du MonsterBook:

Pourtant, même s'il ne s'agit que de convertir une date Julienne en Grégorienne pour ensuite calculer à tous les 30 jours (plus exactement 29,53058) la lune revenant inlassablement, les systèmes d'exploitation ne l'indique pas! Vous trouverez la réponse que vous souhaitez, inspiré du code d'Alan Graff, à l'aide du code source RemObjects Chrome suivant:

NameSpace moonphase;

INTERFACE

Uses 
 System.Text;

type
  Prog = class
    class method MoonPhase(Year,Month,Day:Integer):Double;
    class method Main(Args: array of String);
  end;

IMPLEMENTATION

class method Prog.Main(Args: array of String);
VAR
 I:Integer;
 CircleType:Double;
begin
 For I := 1 to 31 do Begin
  CircleType := MoonPhase(1999, 11, I);
  If CircleType > 0.97 Then
   Console.WriteLine(Convert.ToString(I)+' novembre 1999, Phase de la lune:Pleine lune')
  Else Begin
   If CircleType < 0.03 Then
    Console.WriteLine(Convert.ToString(I)+' novembre 1999, Phase de la lune:Pas de lune')
   Else Begin
    If (CircleType > 0.46) and (CircleType < 0.53) Then Begin
     Console.WriteLine(Convert.ToString(I)+' novembre 1999, Phase de la lune: Quart de lune');
    End;
   End;
  End;
 End;
 For I := 1 to 31 do Begin
  CircleType := MoonPhase(2007, 8, I);
  If CircleType > 0.97 Then
   Console.WriteLine(Convert.ToString(I)+' août 2007, Phase de la lune:Pleine lune')
  Else Begin
   If CircleType < 0.03 Then
    Console.WriteLine(Convert.ToString(I)+' août 2007, Phase de la lune:Pas de lune')
   Else Begin
    If (CircleType > 0.46) and (CircleType < 0.53) Then Begin
     Console.WriteLine(Convert.ToString(I)+' août 2007, Phase de la lune: Quart de lune');
    End;
   End;
  End;
 End;
end;

class method Prog.MoonPhase(Year,Month,Day:Integer):Double;
Var
 M:Double;
 XYear,Century:Integer;
Begin
 If Month <= 2 Then Begin
  Dec(Year);
  Inc(Month,12);
 End;
 Dec(Month,3);
 XYear := Year MOD 100;
 Century := (((Year DIV 100) * 146097)) DIV 4;
 XYear := (XYear * 1461) DIV 4;
 M := (System.Math.Floor(((((Month * 153) + 2) / 5) + Day) + 1721119 + XYear + Century) + 4.867) / 29.53058;
 Result:=System.Math.Abs(2 * (M - System.Math.Floor(M)) - 1);
end;

END.

on obtiendra le résultat suivant:

1 novembre 1999, Phase de la lune: Quart de lune
8 novembre 1999, Phase de la lune:Pas de lune
15 novembre 1999, Phase de la lune: Quart de lune
23 novembre 1999, Phase de la lune:Pleine lune
30 novembre 1999, Phase de la lune: Quart de lune
6 août 2007, Phase de la lune: Quart de lune
13 août 2007, Phase de la lune:Pas de lune
20 août 2007, Phase de la lune: Quart de lune
28 août 2007, Phase de la lune:Pleine lune


Dernière mise à jour : Lundi, le 13 mars 2006