Section courante

A propos

Section administrative du site

Dans les pays occidentaux, il est inévitable de calculer la date de la Pâque chrétienne. Vous trouverez la réponse que vous souhaitez, à l'aide du code source Turbo Basic suivant:

SUB DateOfEaster (year%, month%, day%)
   g% = (year% MOD 19) + 1
   c% = INT(year% / 100) + 1
   x% = INT((3 * c%) / 4) - 12
   z% = INT((8 * c% + 5) / 25) - 5
   d% = INT((5 * year%) / 4) - x% - 10
   e% = INT(11 * g% + 20 + z% - x%) MOD 30
   IF e% < 0 THEN e% = e% + 30
   IF ((e% = 25) AND (g% > 11)) OR (e% = 24) THEN e% = e% + 1
   n% = 44 - e%
   IF n% < 21 THEN n% = n% + 30
   n% = n% + 7 - INT((d% + n%) MOD 7)
   IF n% > 31 THEN
      month% = 4
      day% = n% - 31
   ELSE
      month% = 3
      day% = n%
   END IF
END SUB

DEF FNMonthName$(month)
   SELECT CASE month
    CASE 1: FNMonthName$ = "Janvier"
    CASE 2: FNMonthName$ = "Février"
    CASE 3: FNMonthName$ = "Mars"
    CASE 4: FNMonthName$ = "Avril"
    CASE 5: FNMonthName$ = "Mai"
    CASE 6: FNMonthName$ = "Juin"
    CASE 7: FNMonthName$ = "Juillet"
    CASE 8: FNMonthName$ = "Août"
    CASE 9: FNMonthName$ = "Septembre"
    CASE 10: FNMonthName$ = "Octobre"
    CASE 11: FNMonthName$ = "Novembre"
    CASE 12: FNMonthName$ = "Décembre"
   END SELECT
END DEF


FOR year% = 2000 TO 2014
    CALL DateOfEaster(year%, month%, day%)
    PRINT "Pâque en l'année " + STR$(year%) + " est le jour " + STR$(day%) + " du mois " + FNMonthName$(month%)
NEXT

on obtiendra le résultat suivant:

Pâque en l'année 2000 est le jour 23 du mois Avril
Pâque en l'année 2001 est le jour 15 du mois Avril
Pâque en l'année 2002 est le jour 31 du mois Mars
Pâque en l'année 2003 est le jour 20 du mois Avril
Pâque en l'année 2004 est le jour 11 du mois Avril
Pâque en l'année 2005 est le jour 27 du mois Mars
Pâque en l'année 2006 est le jour 16 du mois Avril
Pâque en l'année 2007 est le jour 8 du mois Avril
Pâque en l'année 2008 est le jour 23 du mois Mars
Pâque en l'année 2009 est le jour 12 du mois Avril
Pâque en l'année 2010 est le jour 4 du mois Avril
Pâque en l'année 2011 est le jour 24 du mois Avril
Pâque en l'année 2012 est le jour 8 du mois Avril
Pâque en l'année 2013 est le jour 31 du mois Mars
Pâque en l'année 2014 est le jour 20 du mois Avril


Dernière mise à jour : Mardi, le 28 juillet 2015