Section courante

A propos

Section administrative du site

Créer du son

La plupart des programmeurs utilisent le son de l'ordinateur à deux fins : créer de la musique et générer des effets sonores. Avant d'entrer dans les «subtilités» de la programmation sonore, jetons un coup d'oeil sur la structure d'un programme sonore typique... et vous donner un court programme sonore que vous pourrez expérimenter.

Structure d'un programme sonore

Pour commencer, il y a cinq réglages à connaître pour générer du son sur votre Commodore 64 : volume, attaque/décroissance, maintien/relâchement (ADSR), contrôle de la forme d'onde et haute fréquence/basse fréquence. Les trois premiers paramètres sont généralement réglés une fois au début de votre programme. Les réglages de haute et basse fréquence doivent être réglés pour chaque note que vous jouez. Le contrôle de la forme d'onde démarre et arrête chaque note.

Exemple de programme sonore

Avant de commencer, vous devez choisir une voix. Il y a 3 voix. Chaque voix nécessite des numéros de réglage de son différents pour la forme d'onde, ... Vous pouvez jouer 1, 2 ou 3 voix ensemble mais notre échantillon n'utilise que la voix numéro 1. Tapez ce programme ligne par ligne... assurez-vous d'appuyer sur la touche RETURN après chaque ligne : première puce sonore claire.

  • Réglez le volume au réglage le plus élevé.
  • Réglez les taux d'attaque/décroissance pour définir la vitesse à laquelle une note monte et descend de son niveau de volume maximal (0 à 255).
  • Réglez maintien/relâchement pour définir le niveau pour prolonger la note et rater pour la relâcher.
  • Trouvez la note/tonalité que vous voulez jouer dans le tableau des notes de musique et entrez les valeurs de haute fréquence et de basse fréquence pour cette note (chaque note nécessite 2 POKE).
  • Démarrez la forme d'onde avec l'un des 4 réglages standard (17, 33, 65 ou 129).
  • Entrez une boucle temporelle pour définir la durée de la note à jouer (une noire correspond à environ "250" mais peut varier car un programme plus long peut affecter le timing).
  • Désactiver la note.

  1. 5 FOR L=54272 TO 54296:POKE L,0:NEXT
  2. 10 POKE 54296,15
  3. 20 POKE 54277,190
  4. 30 POKE 54278,248
  5. 40 POKE 54273,17:POKE 54272,37
  6. 50 POKE 54276,17
  7. 60 FOR T=1 TO 250:NEXT
  8. 70 POKE 54276,16

Pour entendre la note que vous venez de créer, tapez le mot RUN (exécution) puis appuyez sur la touche RETURN. Pour afficher le programme, tapez le mot LIST et appuyez sur RETURN. Pour le changer, retapez les lignes que vous souhaitez modifier.

Composition de la musique sur votre Commodore 64

Pas besoin d'être musicien pour faire de la musique sur votre Commodore 64 ! Tout ce que vous devez savoir, ce sont quelques chiffres simples indiquant à votre ordinateur à quel point régler le volume, quelles notes jouer, combien de temps les jouer,... Mais d'abord... voici un programme vous donnant une démonstration rapide des incroyables capacités musicales du Commodore 64, en utilisant seulement une des 3 voix distinctes de votre ordinateur.

Tapez le mot NEW et appuyez sur RETURN pour effacer votre programme précédent, puis entrez dans ce programme, tapez le mot RUN et appuyez sur la touche RETURN.

  1. 5 REM ECHELLE MUSICALE : Titre de votre programme
  2. 7 FOR L=54272 TO 54296:POKE L,0:NEXT
  3. 10 POKE 54296,15 :REM Voir le volume au reglage le plus élevé (15).
  4. 20 POKE 54277,9 :REM Regle l'attaque/la decroissance, le niveau de maintien/relachement (chaque note)
  5. 30 POKE 54276,17 :REM Determiner la forme d'onde (type de son).
  6. 40 FOR T=1 TO 300:NEXT :REM Durée (combien de temps) chaque note joue.
  7. 50 READ A :REM Lire le premier chiffre de la ligne 110 DATA.
  8. 60 READ B : REM Lire le deuxieme numéro de la ligne 110 DATA.
  9. 70 IF B=-1 THEN END :REM Se termine quand il a READ -1 a la ligne 900.
  10. 80 POKE 54273,A:POKE 54272,B :REM POKE le premier nombre de DATA a la ligne 110 (A=17) en haute frequence et le deuxieme nombre (8=37) en basse frequence.
  11. 81 REM La prochaine fois, le programme boucle autour de lui READ A comme 19 et B comme 63, et ainsi de suite, et POKE ces nombres dans les emplacements
  12. 82 REM de haute et basse frequence. Le nombre 54273=haute frequence pour la voix 1 et 54272=basse fréquence pour la voix 1.
  13. 85 POKE 54276,17 :REM Note de début
  14. 90 FOR T=1 TO 250:NEXT:POKE 54276,16 ' laissez-le jouer puis arretez la note
  15. 95 FOR T=1 TO 50:NEXT: REM Heure relachement
  16. 100 GOTO 20 :REM Boucle pour reinitialiser le controle et jouer une nouvelle note.
  17. 110 DATA 17,37,19,63,21,154,22,227 : REM Tableau des valeurs des notes de musique. Chaque paire de chiffres représente une note. Par exemple. 17 et 37 représentent "C" de l'octave re, 19 et 63 représentent "0" et ainsi de suite.
  18. 120 DATA 25,177,28,214,32,94,34,175 
  19. 900 DATA -1,-1 :REM Lorsque le programme atteint -1, il desactive le reglage haute/basse frequence et END comme indique a la ligne 70

Pour changer le son en "clavecin", changez la ligne 85 pour lire POKE 54276,33 et la ligne 90 pour lire FOR T=1 TO 250:NEXT:POKE 54276,32 et relancez le programme. (Pour changer de ligne, appuyez sur la touche RUN/STOP pour arrêter le programme, tapez le mot LIST et appuyez sur RETURN, puis retapez la ligne de programme que vous venez de modifier ; la nouvelle ligne remplacera automatiquement la vieille). Ce que nous avons fait ici est de changer la "forme d'onde" d'une onde sonore de forme "triangulaire" en une onde "en dents de scie". Changer la forme d'onde peut changer radicalement le son produit par le Commodore 64... mais... la forme d'onde n'est qu'un des nombreux paramètres que vous pouvez modifier pour créer différentes tonalités musicales et effets sonores ! Vous pouvez également modifier le taux d'attaque/décroissance de chaque note... par exemple, pour passer d'un son "clavecin" à un son plus "banjo", essayez de changer les lignes 20 et 30 pour lire :

  1. 20 POKE 54277,3
  2. 30 POKE 54278,0

Comme vous venez de le voir, vous pouvez faire sonner votre Commodore 64 comme différents instruments de musique. Examinons de plus près le fonctionnement de chaque paramètre de son.

Paramètres audio importants

Volume

Pour activer le volume et le régler au niveau le plus élevé, tapez :

  1. POKE 54296,15

Le réglage du volume va de 0 à 15 mais vous utiliserez 15 la plupart du temps. Pour "éteindre" le volume, tapez :

  1. POKE 54296,0

Vous n'avez qu'à régler le volume une fois au début de votre programme, puisque le même réglage active les trois voix du Commodore 64. (Changer le volume pendant une note de musique ou un effet sonore peut produire des résultats intéressants mais dépasse le cadre de cette introduction.)

Réglage de l'ADSR et du contrôle de la forme d'onde

Vous avez déjà vu comment changer la forme d'onde peut changer l'effet sonore de "xylophone" à "clavecin". Chaque voix a son propre réglage de contrôle de forme d'onde vous permettant de définir quatre types de formes d'onde différents : Triangle, Dents de scie, Impulsion (carré) et Bruit. La commande active également la fonction ADSR du Commodore 64, mais nous y reviendrons dans un instant. Un exemple de réglage de début de forme d'onde ressemble à ceci :

  1. POKE 54276,17

où le premier nombre (54276) représente le réglage de commande pour la voix 1 et le deuxième nombre (17) représente le début d'une forme d'onde triangulaire. Les réglages de chaque combinaison voix et forme d'onde sont indiqués dans le tableau ci-dessous :

  Registre de contrôle Note de début/Nombre d'arrêt
Triangle Dent de scie Impulsion Bruit
Voix 1 54276 17/16 33/32 65/64 129/128
Voix 2 54283 17/16 33/32 65/64 129/128
Voix 3 54290 17/16 33/32 65/64 129/128

Bien que les registres de contrôle soient différents pour chaque voix, les réglages de forme d'onde sont les mêmes pour chaque type de forme d'onde. Pour voir comment il fonctionne, regardez les lignes 85 et 90 du programme de gamme musicale. Dans ce programme, immédiatement après avoir réglé la fréquence à la ligne 80, nous réglons le réglage de contrôle pour la voix 1 à la ligne 85 en utilisant POKE 54276,17. Cela a activé le contrôle pour la voix 1 et l'a réglé sur une forme d'onde triangulaire (17). À la ligne 70, nous mettons POKE 54276,16, laquelle arrête la note. plus tard, nous avons modifié le réglage de début de la forme d'onde de 17 à 33 pour créer une forme d'onde en dents de scie, ce qui a donné à la gamme un effet "clavecin". Voyez comment le paramètre de contrôle et la forme d'onde interagissent ? Le réglage de la forme d'onde est similaire au réglage du volume, sauf que chaque voix a son propre réglage et qu'au lieu de pousser les niveaux de volume, nous définissons des formes d'onde. Ensuite, nous examinerons un autre aspect du son... la fonction ADSR (Attaque/Décroissant et la Stabilisation/Relâchement).

Réglage attaque/décroissance

Comme nous l'avons mentionné précédemment, le réglage de contrôle ADSR définit non seulement la forme d'onde, mais il active également l'ADSR, ou la fonction ADSR (Attaque/Décroissant et la Stabilisation/Relâchement) du Commodore 64. Nous commencerons par regarder le réglage d'attaque/décroissant. Le tableau suivant montre les différents niveaux d'attaque et de décroissance pour chaque voix. Si vous n'êtes pas familier avec les concepts d'attaque et de décroissance du son, vous pourriez penser à "l'attaque" comme la vitesse à laquelle une note/un son monte à son volume maximum. La décroissance est la vitesse à laquelle la note/le son tombe de son niveau de volume le plus élevé au niveau de maintien. Le tableau suivant montre le réglage d'attaque/de déclin pour chaque voix, et les nombres pour chaque réglage d'attaque et de déclin. Notez que vous devez combiner les paramètres d'attaque et de déclin en les additionnant et en entrant le total. Par exemple, vous pouvez définir un taux d'attaque élevé et un taux de décroissance faible en ajoutant le numéro d'attaque élevé (64) au numéro de décroissance faible (1). Le total (65) indiquera à l'ordinateur de régler le taux d'attaque élevé et le taux de décroissance faible. Vous pouvez également augmenter les taux d'attaque en les additionnant (128 + 64 + 32 + 16 = MAX. Taux d'attaque de 240).

Voici les réglages du taux d'attaque/décroissance :

Réglage attaque/décroissance Attaque élevée Attaque moyenne Attaque faible Attaque la plus basse Décroissance élevée Décroissance moyenne Décroissance faible Décroissance la plus faible
Voix 1 54277 128 64 32 16 8 4 2 1
Voix 2 54284 128 64 32 16 8 4 2 1
Voix 3 54291 128 64 32 16 8 4 2 1

Si vous définissez un taux d'attaque sans décroissance, la décroissance est automatiquement zéro et vice-versa. Par exemple, si vous avez POKE 54277,64, vous réglez un taux d'attaque moyen avec zéro décroissance pour la voix 1. Si vous avez POKE 54277,66, vous réglez un taux d'attaque moyen et un faible taux de décroissance (car 66=64+2 et définit les deux paramètres). Vous pouvez aussi additionner plusieurs valeurs d'attaque, ou plusieurs valeurs de décroissance. Par exemple, vous pouvez ajouter une attaque basse (32) et une attaque moyenne (64) pour un taux d'attaque combiné de 96, puis ajouter une décroissance moyenne de 4 et... hop... :

  1. POKE 54277,100

À ce stade, un exemple de programme illustrera mieux l'effet. Tapez le mot NEW, appuyez sur RETURN et tapez ce programme et exécutez-le (RUN) :

  1. 5 FOR L=54272 TO 54296:POKE L,0:NEXT :REM Duree de la note jouee.
  2. 10 PRINT"PRESSE N'IMPORTE QUEL TOUCHE":REM Message à l'ecran.
  3. 20 POKE 54296,15 :REM Regle le volume ou le niveau le plus eleve
  4. 30 POKE 54277,64 :REM Regle l'attaque/la decroissance.
  5. 40 POKE 54273,17:POKE 54272,37:REM Mettez une note dans la voix 1.
  6. 60 GET K$:IF K$=""THEN 60:REM Verifie le clavier.
  7. 70 POKE 54276,17:FOR T=1 T0 200:NEXT:REM Regle le controle de la forme d'onde (triangle).
  8. 80 POKE 54276,16:FOR T=1 TO 50:NEXT:REM Desactive les parametres.
  9. 90 GOTO 20:REM Revenez en arriere et recommence.

Ici, nous utilisons la voix 1 pour créer une note à la fois... avec un taux d'attaque moyen et une décroissance de zéro. La tonalité est la ligne 40. POKE le réglage d'attaque/décroissance avec le nombre 64 active un taux d'attaque moyen. Le résultat ressemble à quelqu'un faisant rebondir une balle dans un baril de pétrole. Maintenant, pour la partie amusante. Appuyez sur la touche RUN/STOP pour arrêter le programme, puis tapez le mot LIST et appuyez sur RETURN. Tapez maintenant cette ligne et appuyez sur RETURN (la nouvelle ligne 40 remplace automatiquement l'ancienne ligne 40) :

  1. 40 POKE 54277,190

Tapez le mot RUN et appuyez sur RETURN pour voir comment ça sonne. Ce que nous avons fait ici, c'est combiner plusieurs paramètres d'attaque et de décroissance. Les réglages sont : attaque haute (128) + attaque basse (32) + attaque la plus basse (16) + décroissance élevée (8) + décroissance moyenne (4) + décroissance basse (2) = 190. Cet effet sonne comme un son de hautbois ou autre instrument "reedy" pourrait faire. Si vous souhaitez expérimenter, essayez de changer la forme d'onde et les nombres d'attaque/de décroissance dans l'exemple de gamme musicale pour voir comment un «hautbois» sonne. Ainsi ... vous pouvez voir que la modification des taux d'attaque/de déclin peut être utilisée pour créer différents types d'effets sonores.

Réglage de maintien/relâchement

Comme l'attaque/la décroissance, le réglage de maintien/relâchement est activé par le contrôle de forme d'onde/ADSR. Le maintien/relâchement vous permet de "prolonger" (soutenir) une partie d'un son particulier, comme la "pédale de relâchement" d'un piano ou d'un orgue vous permettant de prolonger une note. N'importe quelle note ou son peut être soutenu à n'importe lequel des 16 niveaux. Le réglage de maintien/relâchement peut être utilisé avec une boucle FOR...NEXT pour déterminer combien de temps la note sera maintenue au volume soutenu avant d'être relâchée. Le tableau suivant montre les nombres que vous devez mettre dans POKE pour atteindre différents taux de maintien/relâchement :

Maintien/Contrôle Réglage de relâchement Maintien élevé Maintien moyen Maintien bas Maintien la plus basse Relâchement élevé Relâchement moyen Relâchement bas Relâchement la plus basse
Voix 1 54278 128 64 32 16 8 4 2 1
Voix 2 54285 128 64 32 16 8 4 2 1
Voix 3 54292 128 64 32 16 8 4 2 1

Par exemple, si vous utilisez la voix 1, vous pouvez définir un niveau de maintien élevé en tapant : POKE 54278,128 ou vous pouvez combiner un niveau de maintien élevé avec un taux de relâchement faible en ajoutant 128 + 2 puis POKE 54278,130. Voici le même exemple de programme que nous pouvons utilisé avec l'attaque ! Section décroissante ci-dessus... avec une fonction maintien/relâchement ajoutée. Remarquez la différence de sons.

  1. 5 FOR L=54272 TO 54296:POKE L,0:NEXT :REM Duree de la note jouee.
  2. 10 POKE 54296,15 :REM Regle le volume au niveau le plus eleve.
  3. 20 POKE 54277,64 :REM Regle l'attaque/le declin.
  4. 30 POKE 54278,128 :REM Regle le maintien/relachement
  5. 40 POKE 54273,17:POKE 54272,37 :REM POKE une note dans la voix 1.
  6. 50 PRINT"PRESSE N'IMPORTE QUEL TOUCHE" :REM Message a l'ecran.
  7. 60 GET K$:IF K$=""THEN 60 :REM Verifie le clavier.
  8. 70 POKE 54276,17:FOR T=1 TO 200:NEXT :REM Regle le contrôle de la forme d'onde (triangle).
  9. 80 POKE 54276,16:FOR T=1 TO 50:NEXT :REM Desactivez les parametres.
  10. 90 GOTO 60 :REM Revenez en arriere et faites-le

À la ligne 30, nous disons à l'ordinateur de maintenir la note à un niveau de maintien élevé (128 du tableau ci-dessus)... après quoi le ton est relâché à la ligne 80. Vous pouvez faire varier la durée d'une note en modifiant le "compte" à la ligne 70. Pour voir l'effet de l'utilisation de la fonction de relâchement, essayez de changer la ligne 30 en POKE 54278,89 (maintien=80, relâchement=9).

Choix des voix et réglage des valeurs sonores hautes/basses fréquences

Chaque note individuelle sur le Commodore 64 nécessite deux commandes POKE distinctes... une pour la haute fréquence et une pour la basse fréquence. Le tableau des valeurs des notes de musique vous indique les POKE, vous devez jouer n'importe quelle note dans la gamme de huit octaves du Commodore 64. Les commandes POKE haute et basse fréquence sont différentes pour chaque voix que vous utilisez, ce qui vous permet de programmer les 3 voix indépendamment pour créer de la musique à 3 voix ou des effets sonores exotiques.

Les commandes POKE haute et basse fréquence pour chaque voix sont indiquées dans le tableau ci-dessous, contenant également les valeurs de note pour l'octave médiane (cinquième).

Numéro de voix et fréquence Numéro POKE C C# D D# E F F# G G# A A# B C C#
Voix 1/Haute 54273 34 36 38 40 43 45 48 51 54 57 61 64 68 72
Voix 1/Basse 54272 75 85 126 200 52 198 127 97 111 172 126 188 149 169
Voix 2/Haute 54280 34 36 38 40 43 45 48 51 54 57 61 64 68 72
Voix 2/Basse 54279 75 85 126 200 52 198 127 97 111 172 126 188 149 169
Voix 3/Haute 54287 34 36 38 40 43 45 48 51 54 57 61 64 68 72
Voix 3/Basse 54286 75 85 126 200 52 198 127 97 111 172 126 188 149 169

Comme vous pouvez le voir, il y a 2 réglages pour chaque voix, un réglage haute fréquence et un réglage basse fréquence. Pour jouer une note de musique, vous devez mettre POKE avec une valeur dans l'emplacement des hautes fréquences et un POKE avec une autre valeur dans l'emplacement des basses fréquences. En utilisant les paramètres de notre tableau de valeurs de voix/fréquence/note, voici le réglage jouant une note C à partir de la 5e octave (voix 1) :

  1. POKE 54273,34:POKE 54272,75

La même note sur voix 2 serait :

  1. POKE 54280,34:POKE 54279,75

Utilisé dans un programme, il ressemble à ceci :

  1. 5 FOR L=54272 TO 54296:POKE L,0:NEXT
  2. 10 V=54296:W=54276:A=54277:S=54278:H =54273:L=54272:REM Definissez des nombres egaux aux lettres.
  3. 20 POKE V,15:POKE A,190:POKE S,89 :REM POKE volume, forme d'onde, attaque/decroissance.
  4. 30 POKE H,34:POKE L,75:REM POKE haut/bas de notes de frequences
  5. 40 POKE W,33:FOR T=1 TO 200:NEXT:REM Commencer la note, laissez-la jouer
  6. 50 POKE W,32:REM Note d'arret

Jouer une chanson sur le Commodore 64

Le programme suivant peut être utilisé pour composer ou jouer un morceau (en utilisant la voix 1). Il y a deux leçons importantes dans ce programme : Tout d'abord, notez comment nous abrégeons tous les numéros de contrôle longs dans la première ligne du programme... après cela, nous pouvons utiliser la lettre W pour "Waveform" au lieu du nombre 54276.

La deuxième leçon concerne la façon dont nous utilisons les DATA. Ce programme est configuré pour vous permettre d'entrer 3 chiffres pour chaque note : la valeur de la note haute fréquence, la valeur de la note basse fréquence et la durée pendant laquelle la note sera jouée.

Pour cette chanson, on utilise un compteur de durée de 125 pour une croche, 250 pour une noire, 375 pour une noire pointée, 500 pour une blanche et 1000 pour une ronde. Ces valeurs numériques peuvent être augmentées ou diminuées pour correspondre à un tempo particulier ou à vos propres goûts musicaux.

Pour voir comment une chanson est entrée, regardez la ligne 100. Nous avons entré 34 et 75 comme paramètres de haute et basse fréquence pour jouer une note "C" (à partir de l'échantillon d'échelle montré précédemment) puis le nombre 250 pour une noire. Ainsi, la première note de notre chanson est une noire C. La deuxième note est également une noire, cette fois la note est "E" ... et ainsi de suite jusqu'à la fin de notre morceau. Vous pouvez entrer presque n'importe quelle chanson de cette façon, en ajoutant autant de lignes d'instructions DATA que vous en avez besoin. Vous pouvez continuer les numéros de note et de durée d'une ligne à l'autre, mais chaque ligne doit commencer par le mot DATA. DATA -1,-1,-1 devrait être la dernière ligne de votre programme. Cette ligne «termine» la chanson.

Tapez le mot NEW pour effacer votre programme précédent et tapez le programme suivant, puis tapez RUN pour entendre la chanson.

  1. 2 FOR L=54272 TO 54296:POKE L,0:NEXT
  2. 5 V=54296: W=5427 6:A=54277: HF=54273:LF=54272:S=54278:PH=54275:PL=54274
  3. 10 POKE V,15:POKE A,88:POKE PH,15:POKE PL,15:POKE S,89
  4. 20 READ H:IF H=-1 THEN END
  5. 30 READ L
  6. 40 READ D
  7. 60 POKE HF,F:POKE LF,L:POKE W,65
  8. 80 FOR T=1 TO D:NEXT:POKE W,64
  9. 85 FOR T=1 TO 50:NEXT
  10. 90 GOTO 10
  11. 100 DATA 34,75,250,43,52,250,51,97,375,43,52,125,51,97
  12. 105 DATA 250,57,172,250
  13. 110 DATA 51,97,500,0,0,125,43,52,250,51,97,250,57,172
  14. 115 DATA 1000,51,97,500
  15. 120 DATA -1,-1,-1

Création d'effets sonores

Contrairement à la musique, les effets sonores sont plus souvent liés à une "action" de programmation spécifique, comme l'explosion d' un chasseur astro lorsqu'il s'écrase à travers une barrière dans un jeu spatial... ou le buzzer d'avertissement dans un programme commercial indiquant au utilisateur, il est sur le point d'effacer son disque par erreur.

Vous disposez d'un large éventail d'options si vous souhaitez créer différents effets sonores. Voici 10 idées de programmation pouvant vous aider à commencer à expérimenter des effets sonores :

  1. Modifiez le volume pendant qu'une note joue, par exemple pour créer un effet "écho".
  2. Faites varier rapidement entre deux notes pour créer un son "tremblement".
  3. Forme d'onde ... essayez différents réglages pour chaque voix.
  4. Attaque/Décroissance ... pour modifier la vitesse à laquelle un son monte vers son volume "pic" et la vitesse à laquelle il diminue à partir de ce pic.
  5. Maintien/relâchement ... pour changer le maintien en volume d'un effet sonore, et le taux diminue à partir de ce volume.
  6. Effets multivoix ... jouant plus d'une voix en même temps, chaque voix étant contrôlée indépendamment, ou une voix jouant plus ou moins longtemps qu'une autre, ou servant d'"écho" ou de réponse à une première note.
  7. Changer les notes sur la gamme, ou changer les octaves, en utilisant les valeurs du tableau des valeurs des notes musicales.
  8. Utilisez la forme d'onde carrée et différents paramètres d'impulsion pour créer différents effets.
  9. Utilisez la forme d'onde de bruit pour générer un "bruit blanc" pour accentuer les effets sonores tonals ou créer des explosions, des coups de feu ou des pas. Les mêmes notes musicales créant de la musique peuvent également être utilisées avec la forme d'onde de bruit pour créer différents types de bruit blanc.
  10. Combinez plusieurs hautes et basses fréquences en succession rapide sur différentes octaves.
  11. Filtre ... essayez le paramètre POKE supplémentaire.

Exemples d'effets sonores à essayer

Les programmes suivants peuvent être ajoutés à presque tous les programmes BASIC. Ils sont inclus pour vous donner quelques idées de programmation et démontrer la gamme d'effets sonores du Commodore 64.

Remarquez le raccourci de programmation que nous utilisons à la ligne 10. Nous pouvons abréger ces longs numéros de paramètres sonores en les définissant comme des lettres faciles à utiliser (variables numériques). la ligne 10 signifie simplement que ces LETTRES faciles à retenir peuvent être utilisées à la place de ces longs chiffres. Ici, V=volume, W =forme d'onde, A=attaque/décroissance, H=haute fréquence (voix 1) et L=basse fréquence (voix 1). Nous utilisons ensuite ces lettres au lieu de chiffres dans notre programme ... ce qui rend notre programme plus court, la frappe plus rapide et les paramètres sonores plus faciles à mémoriser et à repérer.

Exemples d'une poupée en larmes :

  1. 10 V=54296:W=54276:A=54277: H=54273:L=54272
  2. 20 POKE V,15:POKE W,65:POKE A,15
  3. 30 FOR X=200 TO 5 STEP-2:POKE H,40:POKE L,X:NEXT
  4. 40 FOR X=150 TO 5 STEP-2:POKE H,40:POKE L,X:NEXT
  5. 50 POKE W,0

Son de prise de vue ... en utilisant la voix 1, la forme d'onde de bruit, le volume en fondu :

  1. 10 V=54296:W=54276:A=54277:H =54273:L=54272
  2. 20 FOR X=15 TO 0 STEP -1:POKE V,X:POKE W,129:POKE A,15:POKE H,40:POKE L,200:NEXT
  3. 30 POKE W,0:POKE A,0

Dernière mise à jour : Jeudi, le 23 mars 2023