Prise en charge d'Intel MMX
Le Free Pascal prend en charge les instructions MMX (Multi-Media eXtensions) des microprocesseurs Intel. L'idée du MMX est de traiter plusieurs données avec une seule instruction, par exemple le processeur peut ajouter simultanément 4 mots. Pour implémenter cela efficacement, le langage de programmation Pascal doit être étendu. Ainsi Free Pascal permet d'ajouter par exemple deux array[0..3] of word, si le support MMX est activé. L'opération est effectuée par l'unité MMX et permet aux personnes sans connaissances en assemblage de profiter des extensions MMX.
Voici un exemple :
- Program MMXSamples;
-
- Uses
- MMX; { inclusion des types de données prédéfinis }
-
- Const
- { tmmxword=array[0..3] of Word;, déclaré par l'unité MMX }
- w1:tmmxword=(111,123,432,4356);
- w2:tmmxword=(4213,63456,756,4);
-
- Var
- w3:tmmxword;
- i:LongInt;
-
- BEGIN
- If is_mmx_cpu Then Begin { is_mmx_cpu est exporté à partir de l'unité MMX }
- {$mmx+} { Active le MMX }
- w3:=w1+w2;
- {$mmx-}
- End
- Else
- Begin
- For i:=0 to 3 do w3[i]:=w1[i]+w2[i];
- End;
- END.
Prise en charge de la saturation
Un point important de MMX est le support des opérations saturées. Si une opération devait provoquer un débordement, la valeur reste à la valeur la plus élevée ou la plus basse possible pour le type de données : si vous utilisez des valeurs d'octet, vous obtenez normalement 250+12=6. C'est très gênant lors de manipulations de couleurs ou de changements d'échantillons audio, lorsque vous devez ajouter un mot et vérifier si la valeur est supérieure à 255. La solution est la saturation : 250 + 12 donne 255. Les opérations saturées sont prises en charge par l'unité MMX. Si vous voulez les utiliser, il vous suffit d'activer la directive de saturation : $saturation+.
Voici un exemple :
- Program SaturationSample;
-
- Uses MMX;
-
- Var
- Audio1:tmmxword;
- i:smallint;
-
- Const
- Helpdata1:tmmxword=($c000,$c000,$c000,$c000);
- Helpdata2:tmmxword=($8000,$8000,$8000,$8000);
-
- BEGIN
- { audio1 contient quatre échantillons audio 16 bits }
- {$mmx+}
- { Le $8000 est convertie comme zéro, multiplier les données par 0,75 }
- Audio1:=(Audio1+Helpdata2)*(Helpdata1);
- {$saturation+}
- { éviter les débordements (toutes valeurs > $FFFF devient $FFFF) }
- Audio1:=(Audio1+Helpdata2)-Helpdata2;
- {$saturation-}
- { Multiplier maintenant par 2 et changer en nombre entier }
- For i:=0 to 3 do Audio1[i]:=Audio1[i] shl 1;
- Audio1:=Audio1-Helpdata2;
- {$mmx-}
- END.
Restrictions de la prise en charge de MMX
Au début de 1997, les instructions MMX ont été introduites dans les microprocesseurs Pentium, de sorte que les systèmes multitâches ne sauvegardaient pas les registres MMX nouvellement introduits. Pour contourner ce problème, Intel a cartographié les registres MMX au registre FPU.
La conséquence est que vous ne pouvez pas mélanger les opérations MMX et en virgule flottante. Après avoir utilisé les opérations MMX et avant d'utiliser les opérations en virgule flottante, vous devez appeler la procédure EMMS de l'unité MMX. Cette routine restaure les registres FPU.
Attention : le compilateur n'avertit pas si vous mélangez des opérations en virgule flottante et MMX, alors soyez prudent.
Les instructions MMX sont optimisées pour les opérations multimédia. Il n'est donc pas possible d'effectuer toutes les opérations possibles : certaines opérations donnent une incompatibilité de type.
Une restriction importante est que les opérations MMX ne sont pas contrôlées par intervalle ou débordement, même lorsque vous activez la vérification de l'intervalle et de débordement. Cela est dû à la nature des opérations MMX.
L'unité MMX doit toujours être utilisée lors de l'exécution d'opérations MMX car le code de sortie de cette unité efface les registres MMX. Ne pas le faire entraînerait un plantage du programme. Par conséquent, vous ne devez pas utiliser les opérations MMX dans le code de sortie de vos unités ou programmes, car ces opérations interféreraient avec le code de sortie de l'unité MMX. Le compilateur ne peut pas vérifier cela, vous en êtes donc responsable !
Opérations MMX prises en charge
Les opérations suivantes sont prises en charge dans le compilateur lorsque les extensions MMX sont activées :
- ajout (+)
- soustraction (-)
- multiplication(*)
- logique exclusif ou (XOR)
- logique et (AND)
- logique ou (OR)
- changement de signe (-)
Optimisation du support MMX
Voici quelques conseils utiles pour obtenir des performances optimales :
- L'appel EMMS prend beaucoup de temps, essayez donc de séparer les opérations en virgule flottante et MMX.
- Utilisez MMX uniquement dans les routines de bas niveau car le compilateur enregistre tous les registres MMX utilisés lors de l'appel d'une sous-routine.
- L'opérateur NOT n'est pas supporté nativement par MMX, donc le compilateur doit générer une solution de contournement et cette opération est inefficace.
- Les affectations simples de nombres à virgule flottante n'accèdent pas aux registres à virgule flottante, vous n'avez donc pas besoin d'appeler la procédure EMMS. Ce n'est que lorsque vous faites de l'arithmétique que vous devez appeler la procédure EMMS.