Section courante

A propos

Section administrative du site

Faire des boucles

Supposons que vous souhaitiez saisir cinq nombres et les additionner. Une façon (ne tapez pas ceci à moins que vous ne vous sentiez obligé) est d'écrire :

  1. 10 LET total=0
  2. 20 INPUT a
  3. 30 LET total=total+a
  4. 40 INPUT a
  5. 50 LET total=total+a
  6. 60 INPUT a
  7. 70 LET total=total+a
  8. 80 INPUT a
  9. 90 LET total=total+a
  10. 100 INPUT a
  11. 110 LET total=total+a
  12. 120 PRINT total     

Cette méthode n'est pas une bonne pratique de programmation. C'est peut-être à peu près contrôlable pour cinq nombres, mais vous pouvez imaginer à quel point un programme comme celui-ci pour ajouter dix nombres serait fastidieux, et en ajouter une centaine serait tout simplement impossible.

Le mieux est de configurer une variable pour compter jusqu'à 5, puis d'arrêter le programme, comme ceci (que vous devez saisir) :

  1. 10 LET total=0
  2. 20 LET count=1
  3. 30 INPUT a
  4. 40 REM count=nombre de fois que a a ete saisi jusqu'a présent
  5. 50 LET total=total+a
  6. 60 LET count=count+1
  7. 70 IF count<=5 THEN GO TO 30
  8. 80 PRINT total

Remarquez comme il serait facile de changer la ligne 70 pour que ce programme additionne dix nombres, voire cent.

Ce type de comptage est si utile qu'il existe deux commandes spéciales pour le rendre plus facile : la commande FOR et la commande NEXT. Ils sont toujours utilisés ensemble.

En les utilisant, le programme que vous venez de taper fait exactement la même chose que :

  1. 10 LET total=0
  2. 20 FOR c=1 TO 5
  3. 30 INPUT a
  4. 40 REM c=nombre de fois que a a ete saisi jusqu'a présent
  5. 50 LET total=total+a
  6. 60 NEXT c
  7. 80 PRINT total     

(Pour obtenir ce programme à partir du précédent, il vous suffit d'éditer les lignes 20, 40, 60 et 70. TO est SYMBOL SHIFT avec F.)

Notez que nous avons changé count en c. La variable de comptage - ou variable de contrôle - d'une boucle FOR - NEXT doit avoir une seule lettre pour son nom.

L'effet de ce programme est que c parcourt les valeurs 1 (la valeur initiale), 2, 3, 4 et 5 (la limite), et pour chacune, les lignes 30, 40 et 50 sont exécutées. Ensuite, lorsque c a terminé ses cinq valeurs, la ligne 80 est exécutée.

Une subtilité supplémentaire à cela est que la variable de contrôle n'a pas à augmenter de 1 à chaque fois : vous pouvez changer ce 1 en ce que vous voulez en utilisant une partie STEP dans la commande FOR. La forme la plus générale d'une commande FOR est :

FOR control variable = initial value TO limit STEP step

où la variable de contrôle est une seule lettre, et la valeur initiale, la limite et le pas sont toutes des choses que l'ordinateur peut calculer comme des nombres - comme les nombres eux-mêmes, ou des sommes, ou les noms de variables numériques. Donc, si vous remplacez la ligne 20 du programme par :

  1. 20 FOR c=1 TO 5 STEP 3/2

puis c passera par les valeurs 1, 2,5 et 4. Notez que vous n'avez pas à vous limiter aux nombres entiers, et aussi que la valeur de contrôle n'a pas à atteindre exactement la limite - elle continue à boucler tant qu'elle est inférieur ou égal à la limite. Essayez ce programme, pour afficher les nombres de 1 à 10 dans l'ordre inverse :

  1. 10 FOR n=10 TO 1 STEP -1
  2. 20 PRINT n
  3. 30 NEXT n

Nous avons dit précédemment que le programme continue de boucler tant que la variable de contrôle est inférieure ou égale à la limite. Si vous déterminez ce que cela signifierait dans ce cas, vous verrez que cela donne un non-sens. La règle normale doit être modifiée : lorsque le pas est négatif, le programme continue de boucler tant que la variable de contrôle est supérieure ou égale à la limite.

Vous devez être prudent si vous exécutez deux boucles FOR - NEXT ensemble, l'une à l'intérieur de l'autre. Essayez ce programme, affichant les nombres pour un ensemble complet de six dominos :

  1. 10 FOR m=0 TO 6
  2. 20 FOR n=0 TO m
  3. 30 PRINT m;":";n;" ";
  4. 40 NEXT n
  5. 50 PRINT
  6. 60 NEXT m

Vous pouvez voir que la boucle n est entièrement à l'intérieur de la boucle m - elles sont correctement imbriquées. Ce qu'il faut éviter, c'est d'avoir deux boucles FOR - NEXT se chevauchant sans être entièrement à l'intérieur de l'autre, comme ceci :

  1. 5 REM ce programme est mauvais
  2. 10 FOR m=0 TO 6
  3. 20 FOR n=0 TO m
  4. 30 PRINT m;":";n;" ";
  5. 40 NEXT m
  6. 50 PRINT
  7. 66 NEXT n

Deux boucles FOR - NEXT doivent soit être l'une dans l'autre, soit être complètement séparées.

Une autre chose à éviter est de sauter au milieu d'une boucle FOR - NEXT depuis l'extérieur. La variable de contrôle n'est configurée correctement que lorsque son instruction FOR est exécutée, et si vous manquez cela, l'instruction NEXT embrouillera l'ordinateur. Vous obtiendrez probablement un rapport d'erreur indiquant «NEXT without FOR» ou «variable not found».

Rien ne vous empêche d'utiliser FOR et NEXT dans une commande directe. Par exemple, essayez :

  1. FOR m=0 TO 10: PRINT m: NEXT m

Vous pouvez parfois l'utiliser comme un moyen (quelque peu artificiel) de contourner la restriction que vous ne pouvez pas aller à (GO TO) n'importe où dans une commande - car une commande n'a pas de numéro de ligne. Par exemple :

  1. FOR m=6 TO 1 STEP 0: INPUT a: PRINT a: NEXT m

Le pas de zéro ici fait que la commande se répète indéfiniment.

Ce genre de chose n'est pas vraiment recommandé, car si une erreur survient, vous avez perdu la commande et devrez la retaper - et CONTINUE ne fonctionnera pas.



Dernière mise à jour : Mercredi, le 19 avril 2023