Section courante

A propos

Section administrative du site

En Turbo Basic, il existe déjà une fonction permettant de connaitre l'ArcTangente. Cependant, il peut être intéressant d'en reproduire une pour notre plaisir personnel. Pour remédier à se problème, il suffit de créer une fonction ressemblant à ceci avec un préalable la fonction de racine carré:

DEF FNSquareRoot(X)
    LOCAL A,B,M,XN
    IF X=0.0 THEN FNSquareRoot=0.0:EXIT DEF
    M=1.0
    XN=X
    DO UNTIL XN<2.0  
      XN=0.25*XN
      M=2.0*M
    LOOP 
    DO UNTIL XN>=0.5
      XN=4.0*XN
      M=0.5*M
    LOOP 
    A=XN
    B=1.0-XN
    DO
       A=A*(1.0+0.5*B)
       B=0.25*(3.0+B)*B*B
    LOOP WHILE B>=1.0E-15  
    FNSquareRoot=A*M
END DEF    

DEF FNArcTan(X)
    LOCAL A,N
    A = 1.0 / FNSquareRoot(1.0 + (X * X))
    B = 1.0
    N = 1
    DO UNTIL N>11
       A = (A + B) / 2.0
       B = FNSquareRoot(A * B)
       INCR N
    LOOP
    FNArcTan=X / (FNSquareRoot(1.0 + (X * X)) * A)
END DEF

R=0.0
DO UNTIL R>1.1
   PRINT "ArcTan(" + STR$(R) + ")=" + STR$(FNArcTan(R))
   INCR R,0.1
LOOP

on obtiendra le résultat suivant:

ArcTan(0.00000)= 0.000000
ArcTan(0.10000)= 0.099668
ArcTan(0.20000)= 0.197396
ArcTan(0.30000)= 0.291457
ArcTan(0.40000)= 0.380506
ArcTan(0.50000)= 0.463648
ArcTan(0.60000)= 0.540420
ArcTan(0.70000)= 0.610726
ArcTan(0.80000)= 0.674741
ArcTan(0.90000)= 0.732815
ArcTan(1.00000)= 0.785398


Dernière mise à jour : Mardi, le 28 juillet 2015